Thanks VERY much for all your hard work on this item and for making it available.

I have played around with it and even managed to add my own items to the list. I have also managed to play around with the font and font size in the list.

The only problem I have encountered, (hope it hasnt already been answered cause then I am just wasting your time), is the following;

If My list consists of names, for example,

John, Edgar, Paul …….

The tail of the “g” in Edgar keeps getting chopped off. I have played around with changing item height or font size but it still happens. I suspect the text is inside a frame of some sort and the tail is being chopped because it underhangs the bottom of the frame but I could be wrong.

Any ideas where I can fix this?

Thanks again.

Paul

Hey thanks for the contribution and source code man!! I will try to work this into the code base and put up a version on Github.

You could also call the unserialize method in the getInstance method, and the serialize when appropriate, i.e. when closing the app.

pastebin: http://pastebin.com/z90LLB72

the code in case Pastebin deletes the paste.

Cheers!

Rui Pires

		public function serialize():void
		{
			// save the instance

			var f:File = File.applicationStorageDirectory.resolvePath('imageCache.obj');

			var s:FileStream = new FileStream();
			s.open(f, FileMode.WRITE);

			// now convert the dict to a format we can sereialize
			var writeDict:ArrayCollection = new ArrayCollection();

			for each (var obj:Object in imageDictionary)
			{
				// convert bitmap data
				var bytes:ByteArray = new ByteArray();
				bytes.writeUnsignedInt(obj.data.width); // store width of image
				bytes.writeBytes(obj.data.getPixels(obj.data.rect)); // store bitmapdata as bytearray
				bytes.compress();

				var saveObj:Object = new Object();
				saveObj.bytes = bytes;
				saveObj.id = obj.id;

				writeDict.addItem(saveObj);
			}

			s.writeObject(writeDict);
		}

		public function unserialize():void
		{
			registerClassAlias('BitmapData', BitmapData);

			var f:File = File.applicationStorageDirectory.resolvePath('imageCache.obj');

			var s:FileStream = new FileStream();
			s.open(f, FileMode.READ);

			var readDict:ArrayCollection = s.readObject() as ArrayCollection;
			var newDict:ArrayCollection = new ArrayCollection();

			// convert the byteaerray bitmapdata to a new imageDict

			for each (var readObj:Object in readDict)
			{
				var rawData:ByteArray = readObj.bytes as ByteArray;
				rawData.uncompress();

				var width:int = rawData.readUnsignedInt(); // first 4 bytes (unsigned integer)
				var height:int = ((rawData.length - 4) / 4) / width;

				var bmd:BitmapData = new BitmapData(width, height, true, 0); // 32 bit transparent bitmap
				bmd.setPixels(bmd.rect, rawData); // position of data is now at 5th byte

				var convertedObj:Object = new Object();
				convertedObj.data = bmd;
				convertedObj.id = readObj.id;

				newDict.addItem(convertedObj);

			}

			// we can now use this data instead of the old data
			imageDictionary = newDict;
		}